Interface Block (GLSL)

From OpenGL.org
Jump to: navigation, search
Interface Block (GLSL)
Core in version 4.4
Core since version 3.1
Core ARB extension ARB_uniform_buffer_object, ARB_shader_storage_buffer_object

An Interface Block is a group of GLSL input, output, uniform, or storage buffer variables. These blocks have special syntax and semantics that can be applied to them.

Syntax

Interface blocks have different meanings in their various uses, but they have the same syntax regardless of how they are used. Interface blocks are defined as follows:

storage_qualifier block_name
{
  <define members here>
} instance_name;

This looks like a struct definition, but it is not.

storage_qualifier​ can be one of in​, out​, uniform​, or buffer​ (the latter requires GL 4.3). This defines what kind of interface block is being created.

block_name​ is the true name for the interface block. When the block is referenced in OpenGL code or otherwise talked about in most contexts, this is the name that is used.

instance_name​ is a GLSL name for one or more instances of the block named block_name​. It is optional; if it is present, then all GLSL variables defined within the block must be scoped with the instance name. For example, this defines a uniform block:

uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
} matrices;

To access the projection​ member of this block, you must use matrices.projection​.

If it were defined as follows, without an interface name:

uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
};

You simply use projection​ to refer to it. So the interface name acts as a namespace qualifier. At no time can you use MatrixBlock.projection​ in GLSL.

Because these names are defined globally, they can conflict with other names:

uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
};
 
uniform vec3 modelview;  //Redefining variable. Compile error.

The instance name can also be used to define an array of blocks:

uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
} matrices[3];

This creates 3 separate interface blocks: matrices[0]​, matrices[1]​, and matrices[2]​. These can have separate binding locations (see below), so they can come from different buffer objects.

For uniform and shader storage blocks, the array index must be a dynamically-uniform integral expression. For other kinds of blocks, they can be any arbitrary integral expression.

Note: The instance name is only used by GLSL. OpenGL always uses the actual block name. Thus, the name of the above block is "MatrixBlock[1]​", and the names of its members are "MatrixBlock.projection​" and so forth.

Linking between shader stages allows multiple shaders to use the same block. Interface blocks match with each other based on the block name and the member field definitions. So the same block in different shader stages can have different instance names.

Valid types

Interface blocks cannot contain opaque types. They also cannot contain nested structure definitions, though block members can contain structure members. Just not definitions of new structs. So define them first, then use them within the interface.

Qualifiers

Members of interface blocks can have type qualifiers associated with them. Some of these may be layout qualifiers. For the most part, the available type qualifiers are the set of the qualifiers that would be allowed for non-block variables of that type.

Qualifiers are applied to a block member as they normally would be for a global definition: listed before the variable name in-order:

in BlockName
{
  flat ivec3 someInts; //Flat interpolation.
  vec4 value;          //Default interpolation is smooth.
};

In some cases, members of an interface block cannot use the qualifiers allowable to global definitions. And in some cases, interface block members have additional qualifiers, typically layout qualifiers to control aspects of the variable's layout within the block.

Interface matching

Two interface block definitions in different shaders within the same program can match their definitions if and only if:

  • They use the same block name. Not the same interface name.
  • They define the exact same variables (types and names), in the same order, and with the same qualifiers.
  • If the block is declared as an array of blocks, then the array count must be the same among all definitions. There is an exception: matching interface blocks between different shader stages where one stage outputs single values while the next takes an array, such as Vertex-to-Geometry matching.

If two blocks have the same block name but do not match in their definition or array count, then a linking error will occur.

Matching only matters in certain instances. For example, matching is important when communicating between shaders with input and output interface blocks. The input interface block for the receiving shader must match the output interface block. This is why interface names exist, so that different shaders in the same program can refer to the same variables with a different name qualifier.

Matching matters in these instances, and has the following effects:

  • Between the output block(s) of one shader stage and the input block(s) of the next active shader in the pipeline. A proper match ensures that data is transferred correctly.
  • Between uniform and shader-storage blocks in any shader stage. If two such blocks in different stages match, then the linked program will only advertise one such block to the user. This is a lot like how uniforms are linked together between stages.

Input and output

Input and output blocks are designed to complement each other. Their primary utility is with geometry or tessellation shaders, as these shaders often work with aggregates of input/output values. Blocks make it easy to organize this data.

Interface blocks for inputs/outputs can only be used to aggregate data interfaces between shader stages. Vertex shaders cannot declare an input interface block, and fragment shaders cannot declare an output interface block.

If a shader stage uses an input block and it is linked directly to its previous shader stage, then that stage must provide a matching output block, as defined above. For example, a vertex shader can pass data to a geometry shader using these block definitions:

//Vertex Shader
out VertexData
{
  vec3 color;
  vec2 texCoord;
} outData;
 
//Geometry Shader
in VertexData
{
  vec3 color;
  vec2 texCoord;
} inData[];

Notice that the geometry shader block is defined as an array in the geometry shader. It also uses a different instance name. These work perfectly fine; the GS will receive a number of vertices based on the primitive type it is designed to take.

Note: Input/output interface blocks don't use location​ names for interface matching. So in separable programs, interfaces must match directly by name.

The only types that are valid in input/output blocks are those which are valid as input/output variables.

Buffer backed

Uniform blocks and shader storage blocks work in very similar ways, so this section will explain the features they have in common. Collectively, these are called "buffer-backed blocks" because the storage for their contents come from a Buffer Object.

Note that shader storage blocks are a GL 4.3 feature, and thus are not available unless 4.3 or ARB_shader_storage_buffer_objects is defined.

Matrix storage order

Because the storage for these blocks comes from Buffer Objects, matrix ordering becomes important. Matrices can be stored in column or row-major ordering. Layout qualifiers are used to decide which is used on a per-variable basis.

Note that this does not change how GLSL works with them. GLSL matrices are always column-major. This specification only changes how GLSL fetches the data from the buffer.

Defaults can be set with this syntax:

layout(row_major) uniform;

From this point on, all matrices in uniform blocks are considered row-major. Shader storage blocks are not affected; they would need their own definition (layout(row_major) buffer;​).

A particular block can have a default set as well:

layout(row_major) uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
} matrices[3];

All of the matrices are stored in row-major ordering.

Individual variables can be adjusted as well:

layout(row_major) uniform MatrixBlock
{
  mat4 projection;
  layout(column_major) mat4 modelview;
} matrices[3];

MatrixBlock.projection​ is row-major, but MatrixBlock.modelview​ is column-major. The default is column-major.

Memory layout

The specific size of basic types used by members of buffer-backed blocks is defined by OpenGL. However, implementations are allowed some latitude when assigning padding between members, as well as reasonable freedom to optimize away unused members. How much freedom implementations are allowed for specific blocks can be changed.

There are four memory layout qualifiers: shared​, packed​, std140​, and std430​. Defaults can be set the same as for matrix ordering (eg: layout(packed) buffer;​ sets all shader storage buffer blocks to use packed​). The default is shared​.

packed​: This layout type means that the implementation determines everything about how the fields are laid out in the block. The OpenGL API can be used to query the layout for the members of a particular block. Each member of a block will have a particular byte offset, which you can use to determine how to upload its data. Also, members of a block can be optimized out if they are found by the implementation to not affect the result of the shader. Therefore, the active components of a block may not be all of the components it was defined with.

shared​: This layout type works like packed​, with two exceptions. First, it guarantees that all of the variables defined in the block are considered active; this means nothing is optimized out. Second, it guarantees that the members of the block will have the same layout as a block definition in another program, so long as:

  • The blocks in different programs use the exact same block definition (ignoring differences in variable names and the block name itself).
  • All members of the block use explicit sizes for arrays.

Because of these guarantees, buffer-backed blocks declared shared​ can be used with any program that defines a block with the same elements in the same order. This even works across different types of buffer-backed blocks. You can use a buffer as a uniform buffer at one point, then use it as a shader storage buffer in another. OpenGL guarantees that all of the offsets and alignments will match between two shared​ blocks that define the same members in the same order. In short, it allows the user to share buffers between multiple programs.

std140​: This layout alleviates the need to query the offsets for definitions. The rules of std140​ layout explicitly state the layout arrangement of any interface block declared with this layout. This also means that such an interface block can be shared across programs, much like shared​. The only downside to this layout type is that the rules for packing elements into arrays/structs can introduce a lot of unnecessary padding.

The rules for std140​ layout are covered quite well in the OpenGL specification.

Warning: Implementations sometimes get the std140​ layout wrong for vec3​ components. You are advised to manually pad your structures/arrays out and avoid using vec3​ at all.

std430​: This layout works like std140​, except with a few optimizations in the base offset and alignment for arrays and structs of scalars and vector elements. Note that this layout can only be used with shader storage blocks, not uniform blocks.

Explicit variable layout

Explicit Variable Layout
Core in version 4.4
Core since version 4.4
Core ARB extension ARB_enhanced_layouts

Block binding

Block Binding
Core in version 4.4
Core since version 4.2
Core ARB extension ARB_shading_language_420pack

Each uniform/shader storage block has a binding index. This index references one of a number of slots in the OpenGL context that say which buffer objects to use. When a buffer object is bound to the index reference by a block, then that block will get its data from that buffer.

The block binding indices can be set directly from the shader:

layout(binding = 3) uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
};

Uniform and shader storage blocks have a different set of indices. Uniform block binding indices refer to blocks bound to indices in the GL_UNIFORM_BUFFER​ indexed target with glBindBufferRange. Shader storage block binding indices refer to blocks bound to indices in the GL_SHADER_STORAGE_BUFFER​ target.

For arrays of blocks, the binding syntax sequentially allocates indices. So this definition:

layout(binding = 2) uniform MatrixBlock
{
  mat4 projection;
  mat4 modelview;
} matrices[4];

There will be 4 separate blocks, which use the binding indices 2, 3, 4, and 5.

Block bindings can also be set manually from OpenGL. The function to do this depends on whether it is a uniform block or a shader storage block. See their individual sections.

Once a binding is assigned, the storage can be bound to the OpenGL context with glBindBufferRange (or glBindBufferBase for the whole buffer). Each type of buffer-backed block has its own target. Uniform blocks use GL_UNIFORM_BUFFER​, and shader storage blocks use GL_SHADER_STORAGE_BUFFER​.

Uniform blocks

Uniform blocks cannot use std430​ layout.

To set the block binding from OpenGL, you must first get the index for that uniform block. To do that, you may use one of these two functions:

GLuint glGetProgramResourceIndex( GLuint program​​, GLenum programInterface​​, const char *name​ );
GLuint glGetUniformBlockIndex( GLuint program​​, const char *name​​ );

The first function is only available in GL version 4.3 or if ARB_program_interface_query is available. The latter is always available. If you use glGetProgramResourceIndex, the programInterface​​ parameter should be GL_UNIFORM_BLOCK​.

If name​ specifies a block that is inactive, or specifies a block that isn't defined in program​, then GL_INVALID_INDEX​ is returned.

Once the index is retrieved, it can be used to set the buffer binding with this function:

void glUniformBlockBinding( GLuint program​​, GLuint uniformBlockIndex​​, GLuint uniformBlockBinding​​ );

This causes the uniform block specified by uniformBlockIndex​​ in program​​ to use the uniform buffer binding location uniformBlockBinding​​.

There are only GL_MAX_UNIFORM_BUFFER_BINDINGS​ binding locations available. So uniformBlockBinding​​ must be less than this value.

In a relatively recent change, the rules in GL 4.3 for aggregating uniform block definitions in different shaders have changed. If a uniform block (and only a uniform block. Not other forms of interface blocks) uses an instance name, then all references in the linked program to that uniform block name must also use an instance name. They don't have to use the same instance name, just some instance name. This way, all code that uses a uniform block in a particular program will scope their variables in the same way (though again, not necessarily with the same instance name).

Shader storage blocks

If the last member variable of a shader storage block is declared with an indeterminate array length (using []​), then the size of this array is determined at the time the shader is executed. The size is basically the rest of the buffer object range that was attached to that binding point.

For example, consider the following:

layout(std430, binding = 2) buffer MyBuffer
{
  mat4 matrix;
  float lotsOfFloats[];
};

The number of float​ variables in lotsOfFloats​ depends on the size of the buffer range that is attached to the binding point. matrix​ will be 64 bytes in size, so the number of elements in lotsOfFloats​ will be (size of the bound range minus 64) / 4. Thus, if we bind with this:

glBindBufferRange(GL_SHADER_STORAGE_BUFFER, 2, buffer, 0, 128);

There will be (128 - 64) / 4, or 16 elements in lotsOfFloats​. Thus, lotsOfFloats.length()​ will return 16. It will return a different value depending on the size of the bound range.

Manual block binding

As with uniform blocks, you must get the index to the shader storage block in order to manually bind it. There is only one function to do this:

GLuint glGetProgramResourceIndex( GLuint program​​, GLenum programInterface​​, const char *name​ );

In this case, programInterface​ should be GL_SHADER_STORAGE_BLOCK​​.

If name​ specifies a block that is inactive, or specifies a block that isn't defined in program​, then GL_INVALID_INDEX​ is returned.

Once the index is retrieved, it can be used to set the buffer binding with this function:

void glShaderStorageBlockBinding( GLuint program​​, GLuint storageBlockIndex​​, GLuint storageBlockBinding​​ )

This causes the shader storage block specified by storageBlockIndex​​ in program​​ to use the shader storage buffer binding location storageBlockBinding​​.

There are only GL_MAX_SHADER_STORAGE_BUFFER_BINDINGS​ binding locations available. So storageBlockBinding​​ must be less than this value.